# Compaq OpenVMS
システム管理者マニュアル

前へ | 次へ | 目次 | 索引

### 15.5.1.8 DECnet に関連するパラメータを上書きする方法

DECnet の存在 (または不在) に関する AUTOGEN の観測を上書きするには， MODPARAMS.DAT のパラメータ LOAD_DECNET_IMAGES を TRUE (または FALSE) に設定します。同期ネットワーク・ハードウェアがないシステムにおいて非同期 DECnet を実行したい場合には，設定値を制御すると役に立ちます。

### 15.5.1.9 NPAGEDYN と NPAGEVIR の値の設定

物理メモリが多くない OpenVMS システムのために，AUTOGEN は NPAGEDYN が物理メモリの 10% を越えた時，あるいは NPAGEVIR が物理メモリの 33% を越えた時に，

AUTOGEN は計算値を， NPAGEDYN は物理メモリの 20 %に NPAGEVIR は物理メモリの 50 % に制限しています。これらの計算値は物理メモリが16MB 以下のほとんどのシステムで妥当な値です。システムでこれ以上大きな値を設定する必要がある場合， MODPARAMS.DAT に書き込むことによって AUTOGEN の計算値を上書きすることができます。

## 15.5.2 AUTOGEN フィードバックに必要な最小稼働時間の指定 (VAX のみ)

VAX システムでは，システムの稼働時間がシステムの正常な作業負荷を十分に反映していなければ，AUTOGEN フィードバックは有効ではありません。省略時の設定では，AUTOGEN はデータが作成されてから 24 時間より多く経過しないとフィードバックを使用しません。 VAX システムでは，論理名 AGEN$FEEDBACK_REQ_TIME を定義することにより，省略時の設定と異なる最小稼働時間 (データの生成後，フィードバックに利用できない期間) を時間単位で指定できます。

たとえば，論理名を次のように定義した場合， AUTOGEN はデータが生成されてから 19 時間より多く経過しないとフィードバック・データを使用しません。

    $
    DEFINE/SYSTEM AGEN$FEEDBACK_REQ_TIME 19

システムが起動するたびにこの論理名を定義するためには，このコマンドを SYLOGICALS.COM に追加します。

## 15.5.3 外部パラメータ・ファイルの MODPARAMS.DAT への取り込み

外部のパラメータ・ファイルを MODPARAMS.DAT に取り込むことができます。たとえば，あるシステム・パラメータを VAXcluster または OpenVMS Cluster 環境内のすべてのノードと同じ値に設定すると同時に，他のシステム・パラメータをノード固有の値にしたいことがあります。そのような場合は，クラスタ共通の値を別のファイルで指定し，クラスタ内の各システムの MODPARAMS.DAT にそのファイルを取り込むようにします。

パラメータ・ファイルを取り込むためには， MODPARAMS.DAT，あるいは MODPARAMS.DAT に取り込まれる任意のパラメータ・ファイルに次の形式でコマンドを追加します。

    AGEN$INCLUDE_PARAMS   完全なディレクトリ指定:ファイル名

例

CLUSTERPARAMS.DAT という名前のクラスタ共通のパラメータ・ファイルを取り込む場合には，まず，次の名前の共通のパラメータ・ファイルを作成します。

> SYS$COMMON:[SYSEXE]CLUSTERPARAMS.DAT

次に，各クラスタのシステム固有のディレクトリの MODPARAMS.DAT ファイルに次の行を追加します。

    AGEN$INCLUDE_PARAMS SYS$COMMON:[SYSEXE]CLUSTERPARAMS.DAT

## 15.5.4 DCL 文のログの停止

MODPARAMS.DATの内容は，DCL 文として評価されます。したがって，シンボルにシステム・パラメータではない名前 (たとえば，他の値に基づくスクラッチ変数または条件付き割り当て) を割り当てることができます。通常，そのような割り当てはすべて AGEN$PARAMS.REPORTにログが取られ，ログが取られた多くの文によって必要のない大きなファイルが作成されていきます。

このような割り当てすべてにドル記号($)を接頭辞として付けることにより， AGEN$PARAMS.REPORTにログを取られたくない割り当てを指定することができます。 AUTOGENは， MODPARAMS.DATの中のドル記号で始まるレコードを検出すると，既知のシステム・パラメータのリストをチェックしないで， AGEN$PARAMS.REPORTにこのレコードのログを取りません。

# 15.6 AUTOGEN レポートの自動化

バッチ・モードのコマンド・プロシージャを作成して，AUTOGEN を定期的に自動実行させ，その結果得られるフィードバック・レポートを適切な Mail アカウントに送信しておくようにしてください。 例 15-2 は，このようなコマンド・プロシージャの例です。

注意 このコマンド・プロシージャでは，システム・パラメータの適切な値を計算してレポートを送信するためにだけ AUTOGEN を実行しています。 AUTOGEN の実行によりシステム・パラメータを変更したり，システムを再ブートすることはありません。レポートを調べた結果，システム・パラメータを変更することになった場合には， 第 15.6.1 項 にある指示に従ってください。

例 15-2 に示したコマンド・プロシージャは， AUTOGEN を 2 段階に分けて実行します。第 1 段階では， AUTOGEN を作業負荷がピークになる時間帯に実行し，現実的なシステムの作業負荷のデータを収集します。この段階ではシステムの性能が低下することはありません。第 2 段階では，AUTOGEN をシステムの作業負荷が軽い時間帯に実行し，第 1 段階で収集したデータを解釈します。

このプロシージャで，ファイル AGEN$PARAMS.REPORT に含まれている結果のレポートが SYSTEM アカウントに送信されます。このレポートを定期的に検討し，システムの負荷が変更されているかどうかを調べてください。

例 15-2 に，コマンド・プロシージャの例を示します。このプロシージャを参考にして，使用中のシステム構成に合ったコマンド・プロシージャを作成してください。

例 15-2 AUTOGEN コマンド・プロシージャの例
    $ BEGIN$:   ! ++++++++++ AGEN_BATCH.COM ++++++++++
    $  on warning then goto error$
    $  on control_y then goto error$
    $!
    $! Setup process
    $!
    $! Set process information
    $  set process/priv=all/name="AUTOGEN Batch"
    $! Keep log files to a reasonable amount
    $  purge/keep=5 AGEN_Batch.log
    $  time = f$time()                              ! Fetch current time
    $  hour = f$integer(f$cvtime(time,,"hour"))     ! Get hour
    $  today = f$cvtime(time,,"WEEKDAY")            ! Get Day of the week
    $  if f$integer(f$cvtime(time,,"minute")) .ge. 30 then hour = hour + 1
    $!
    $! Start of working day...
    $!
    $ 1AM$:
    $  if hour .le. 2
    $     then
    $     next_time = "today+0-14"
    $     gosub submit$                             ! Resubmit yourself
    $     set noon
    $!

    $!      Run AUTOGEN to TESTFILES using the parameter values collected earlier

    $!      in the day (i.e., yesterday at 2:00pm)
    $       if today .eqs. "Tuesday" .OR. today .eqs. "Thursday" .OR. -
               today .eqs. "Saturday"
    $          then
    $            @sys$update:autogen GETDATA TESTFILES feedback (2)
    $            mail/sub="AUTOGEN Feedback Report for system-name" -
                    sys$system:agen$params.report system (3)
    $            ! Clean up
    $            purge/keep=7 sys$system:agen$feedback.report (4)
    $            purge/keep=7 sys$system:agen$feedback.dat
    $            purge/keep=7 sys$system:params.dat
    $            purge/keep=7 sys$system:autogen.par
    $            purge/keep=7 sys$system:setparams.dat
    $            purge/keep=7 sys$system:agen$addhistory.tmp
    $            purge/keep=7 sys$system:agen$addhistory.dat
    $        endif
    $     goto end$
    $     endif
    $!
    $ 2PM$:
    $  if hour .le. 15
    $     then
    $     next_time = "today+0-17"
    $     gosub submit$
    $     if today .eqs. "Monday" .OR. today .eqs. "Wednesday" .OR. -
             today .eqs. "Friday"
    $        then
    $          @sys$update:autogen SAVPARAMS SAVPARAMS feedback (1)
    $        endif
    $     goto end$
    $     endif
    $!
    $ 5PM$:
    $  if hour .le. 18
    $     then
    $     next_time = "tomorrow+0-1"
    $     gosub submit$
    $     endif
    $!
    $! End of working day...
    $!
    $ END$:     ! ---------- BATCH.COM ----------
    $  exit
    $!++
    $! Subroutines
    $!--
    $!
    $ SUBMIT$:
    $  submit/name="AGEN_Batch"/restart/noprint - (5)
       /log=AGEN_batch.log -
       /queue=sys$batch/after="''next_time'" sys$system:AGEN_batch.com
    $  return
    $!++
    $! Error handler
    $!--
    $ ERROR$:
    $  mail/sub="AGEN_BATCH.COM - Procedure failed." _nl: system
    $  goto end$

次に，このコマンド・プロシージャで実行されるタスクを説明します。

1. 作業負荷がピークになる時間帯に AUTOGEN の第 1 段階を実行し，実際の作業負荷のデータを収集する。このコマンドは非常に高速なイメージを実行するため，システムの応答性を低下させることはない。

2. 作業負荷が軽い時間帯に AUTOGEN の第 2 段階を実行し，第 1 段階で収集したデータを解釈する。

3. AGEN$PARAMS.REPORT という名前の結果のレポート・ファイルを SYSTEM アカウントにメールする。

4. 作成したファイルを削除する。

5. コマンド・プロシージャを再びキューに登録する。

## 15.6.1 AUTOGEN レポートを調べた後のパラメータ値の変更

第 15.6 節 で説明したコマンド・プロシージャのレポートにおいて， AUTOGEN の計算結果が現在値と異なっている場合には，次に示すいずれかの方法で，AUTOGEN の設定内容を修正してください。

- ただちにシステムをシャットダウンして再ブートできる場合には，次のコマンドを実行する。

      $ @SYS$UPDATE:AUTOGEN GETDATA REBOOT FEEDBACK

- ただちにシステムのシャットダウンと再ブートを行うことができない場合には，次のコマンドを実行してシステム・パラメータを再設定する。

      $ @SYS$UPDATE:AUTOGEN GETDATA SETPARAMS FEEDBACK

  新しいパラメータは，システムのブート後，有効になる。

# 15.7 SYSMAN ユーティリティによるシステム・パラメータの管理

注意 システム・パラメータを変更する場合には，できるだけ AUTOGEN を使用してください。詳細は 第 15.5 節 を参照してください。また，ノード・グループに関するシステム・パラメータを表示したり，パラメータを一時的に変更したい場合には，SYSMAN を使用してください。

システム管理ユーティリティ (SYSMAN) を使用すると， 1 つのシステムだけではなく，クラスタ全体，あるいはノードの任意のグループに対応するシステム・パラメータを調べたり，変更することができます。 SYSMAN で利用できる PARAMETERS コマンドは， OpenVMS のシステム生成ユーティリティ (SYSGEN) のパラメータ設定機能を持っています。

次に，SYSMAN ユーティリティを使ってシステム・パラメータを管理できる作業を示します。

作業 | 参照箇所
--- | ---
パラメータ値の表示 | 第 15.7.2 項
パラメータ・ファイル内の現在値の変更 | 第 15.7.3 項
稼働中のシステムのアクティブ値の変更 1 | 第 15.7.4 項

1ダイナミック・システム・パラメータだけに適用

表 15-3 に，SYSMAN が提供するコマンドと機能を示します。

表 15-3 SYSMAN PARAMETERS コマンド
コマンド | 機能
--- | ---
PARAMETERS SHOW | パラメータ値を表示する。
PARAMETERS USE | パラメータのセットを，メモリまたはディスクから調査または変更のための一時作業領域に読み込む。ファイル名，または追加パラメータ ACTIVE か CURRENT が必要。
PARAMETERS SET | パラメータ値を変更する。変更内容は作業領域内でのみ有効。変更内容をより永久的なものにするためには， PARAMETERS WRITE コマンドが必要。
PARAMETERS WRITE | 作業領域の内容をメモリまたはディスクに書き込む。ファイル名，または追加パラメータ ACTIVE か CURRENT が必要。

一時作業領域についての詳細は， 第 15.7.1 項 を参照してください。

## 15.7.1 パラメータ値と SYSMAN について

第 15.1.1 項 で説明しているように，システム・パラメータの値にはいくつかの種類があります。簡単にまとめると 現在値 とは，ディスク上の省略時のパラメータ・ファイルに格納されている値のことです。 アクティブ値 とは，メモリ内に格納され，システムの稼働中に使用される値のことです。これらの値のほかにも，SYSMAN はディスク上の独自の作業領域にパラメータ値を一時的に書き込みます。この値を一時値と呼びます。 図 15-2 は，この 3 種類の値と， SYSMAN コマンドがそれらの値にどう影響するかを示しています。次に，図中の動作を説明します。

1. WRITE ACTIVE は，一時的パラメータ値をメモリに書き込む。

2. USE ACTIVE は，値をメモリから作業領域に読み込む。ユーザはここで値を変更することができる。

3. WRITE CURRENT は，一時的パラメータ値をディスクに書き込む。書き込まれた値が現在の値となる。次にシステムをブートしたとき，これらの値がアクティブになる。

4. USE CURRENT は，現在の値をディスクから作業領域に読み込む。ユーザはここで値を変更することができる。

図 15-2 SYSMAN パラメータの一時値，アクティブ値，現在値

セッション中にパラメータ値を表示または変更する場合，通常のセッションでは次の手順に従ってください。

1. USE コマンドを使って，パラメータの値を SYSMAN の一時作業領域に読み込む。アクティブ値を読み込むときには USE ACTIVE を，現在値を読み込むときには USE CURRENT をそれぞれ使用する。

2. SHOW コマンドを使って，パラメータ値を表示する。

3. SET コマンドを使って，パラメータ値を変更する。変更した値を有効にするには， WRITE コマンドを実行しなければならない。

4. WRITE コマンドを使って，変更内容を有効にする。

   - WRITE ACTIVE を実行すると，パラメータの値はアクティブ値に書き込まれる。ただし，アクティブ値を変更できるのはダイナミック・パラメータの場合だけである。

   - WRITE CURRENT を実行すると，パラメータの値は現在値に書き込まれる。

システム・パラメータについての詳細は，『Compaq OpenVMS システム管理ユーティリティ・リファレンス・マニュアル』を参照してください。

## 15.7.2 SYSMAN によるパラメータ値の表示

SYSMAN の PARAMETERS SHOW コマンドを使用すると，クラスタ内のすべてのノードのパラメータ値を表示することができます。

例

1. パラメータに関する情報の表示方法を示す。 /LGI 修飾子を使用すると，すべてのログイン・セキュリティ制御パラメータを表示する。その他にも，/ACP，/ALL，/SPECIAL などのパラメータを表示できる。パラメータとパラメータ・カテゴリについては，『Compaq OpenVMS システム管理ユーティリティ・リファレンス・マニュアル』を参照。

       $ RUN SYS$SYSTEM:SYSMAN
       SYSMAN> PARAMETERS SHOW/LGI

       Parameters in use: Active
       Parameter Name            Current    Default     Min.     Max.     Unit  Dynamic
       --------------            -------    -------    -------  -------   ----  -------
       LGI_BRK_TERM                    0          1         0         1 Boolean    D
       LGI_BRK_DISUSER                 0          0         0         1 Boolean    D
       LGI_PWD_TMO                    30         30         0       255 Seconds    D
       LGI_RETRY_LIM                   3          3         0       255 Tries      D
       LGI_RETRY_TMO                  20         20         0       255 Seconds    D
       LGI_BRK_LIM                     5          5         0       255 Failures   D
       LGI_BRK_TMO                   300        300         0        -1 Seconds    D
       LGI_HID_TIM                   300        300         0        -1 Seconds    D

2. 次の例では， SYSMAN を起動し，NODE21 および NODE22 から構成されるローカル・クラスタを環境として指定する。また，ユーザ，ターミナル，ノードのログインを試みる時間 (秒数) を制御する LGI_BRK_TMO パラメータのアクティブ値を表示する。この例では，アクティブ値は 600 である。

       $ RUN SYS$SYSTEM:SYSMAN
       SYSMAN> SET ENVIRONMENT/CLUSTER
       %SYSMAN-I-ENV, Current command environment:
          Clusterwide on local cluster
          Username MORIN    will be used on nonlocal nodes
       SYSMAN> PARAMETERS SHOW LGI_BRK_TMO

       Node NODE21:   Parameters in use: ACTIVE
       Parameter Name         Current   Default   Minimum    Maximum Unit  Dynamic
       --------------         -------   -------   -------    ------- ----  -------
       LGI_BRK_TMO                600       300         0         -1 Seconds     D

       Node NODE22:   Parameters in use: ACTIVE
       Parameter Name         Current   Default   Minimum    Maximum Unit  Dynamic
       --------------         -------   -------   -------    ------- ----  -------
       LGI_BRK_TMO                600       300         0         -1 Seconds     D

## 15.7.3 SYSMAN によるパラメータ・ファイルの変更

SYSMAN の PARAMETERS WRITE コマンドを使用すると，システム・パラメータ値およびシステム固有のスタートアップ・コマンド・プロシージャを，ユーザが選択したパラメータ・ファイル，ディスク上の現在のシステム・パラメータ・ファイルに書き込むことができます。

DCL の SET MESSAGE コマンドを使ってシステム・メッセージの形式を変更していない限り， PARAMETERS WRITE CURRENT コマンドを実行すると，メッセージが OPCOM に送信され，イベントが記録されます。

注意 PARAMETERS WRITE CURRENT コマンドを実行すると，現在操作している値だけではなく，パラメータのすべてのアクティブ値または現在値がディスクに書き込まれます。

例

1. 新しいパラメータ指定ファイルを作成する。

       SYSMAN> PARAMETERS WRITE SYS$SYSTEM:NEWPARAM

2. PARAMETERS SET コマンドに続けて PARAMETERS WRITE コマンドを実行すると，ディスク上の現在のパラメータ・ファイルが変更される。

       SYSMAN> PARAMETERS SET LGI_BRK_TMO 300
       SYSMAN> PARAMETERS WRITE CURRENT

前へ | 次へ | 目次 | 索引